home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Cream of the Crop 26
/
Cream of the Crop 26.iso
/
editor
/
par.zip
/
DEVELOP.BAT
< prev
next >
Wrap
DOS Batch File
|
1997-06-27
|
2KB
|
58 lines
@ECHO OFF
REM ---------------------------------------------------------------------
REM - Here we check that we have at least three parameters:
REM - The save position, the POM file, and the input file.
REM ---------------------------------------------------------------------
IF NOT (%3) == () GOTO OKPARM
ECHO Please see "Effective Use of Batch Files" in the documentation
ECHO file (MANUAL.DOC) for an explanation of the DEVELOP.BAT batch file.
GOTO QUIT
:OKPARM
:MENU
REM ---------------------------------------------------------------------
REM - The PSMENU menu utility is included in the standard Parse-O-Matic
REM - package. Type PSMENU_D at the DOS prompt for a brief description.
REM ---------------------------------------------------------------------
PSMENU_D POM DEVELOP %1
IF ERRORLEVEL 10 GOTO QUIT
IF ERRORLEVEL 4 GOTO OUTPUT
IF ERRORLEVEL 3 GOTO PARSE
IF ERRORLEVEL 2 GOTO EDIT
IF ERRORLEVEL 1 GOTO INPUT
:INPUT
SEE %3
GOTO MENU
:EDIT
REM ---------------------------------------------------------------------
REM - You may wish to change the following line to use a different
REM - text editor. (QEdit and Boxer are good shareware text editors.
REM - Windows users may wish to use NotePad.)
REM ---------------------------------------------------------------------
EDIT %2
GOTO MENU
:PARSE
REM ---------------------------------------------------------------------
REM - We include parameters 4, 5 and 6 here, in case you wish to add the
REM - /L or /Q parameters to the command line. In most cases, however,
REM - they will be null (empty).
REM ---------------------------------------------------------------------
POM %2 %3 %4 %5 %6
GOTO MENU
:OUTPUT
IF NOT (%4) == () GOTO OKOUT
ECHO You did not specify an output file. Perhaps your POM file
ECHO specifies the output file with the OFILE command.
GOTO MENU
PAUSE
:OKOUT
SEE %4
GOTO MENU
:QUIT